[P3D][FSX] Tentative de méthode de réalisation

mameloose · [↑]

Garde la console c'est plus simple et bien sûr que tu peux écrire un commentaire dans les cases descriptif

Neutrino · [↑]

Ok

Neutrino · [↑]

La fabrication des différentes radios avance, je suis entrain de programmer en sioc le réglage des unités sur le transpondeur mais je bute sur un os.

Voici ce que j'utilise:

Avec Sioc:
- un encodeur cts 288 avec inputs 2 et 3 sur la master (avec le gnd correspondant)
- j'utilise le joystick 64#0 pour décrément avec l'offset $3340 bit 0
- j'utilise le joystick 64#1 pour incrément avec l'offset $3340 bit 1
- les fonctions SETBIT et CLEARBIT

Avec Fsuipc:
- joystick64#0 => le controle XPNDR_1_DEC
- joystick64#1 => le controle XPNDR_1_INC

Mon code sioc:

Var 0001, name Xpndr_1, Link FSUIPC_INOUT, Offset $3340, Length 4

Var 0002, name Enc_Xpndr_1, Link IOCARD_ENCODER, Input 2, Aceleration 1, Type 2
{
IF &Enc_Xpndr_1 < 0
{
&Xpndr_1 = SETBIT 0
}
ELSE
{
&Xpndr_1 = CLEARBIT 0
}
IF &Enc_Xpndr_1 > 0
{
&Xpndr_1 = SETBIT 1
}
ELSE
{
&Xpndr_1 = CLEARBIT 1
}
}

Résultat:
- le changement des unités sur le transpondeur ne se fait que lors du premier cran de l'encodeur mais plus après.

Par exemple:
- le chiffre des unités est au départ = 0
- 1er cran +1 de l'encodeur => affichage = 1 jusque là c'est bon
- 2ieme cran +1 de l'encodeur => l'affichage reste à 1 idem pour les crans successifs
En fait seul le 1er incrément ou décrément est pris en compte mais pas les suivants.

Je suppose que le problème vient de la programmation puisque le même encodeur raccordé à une carte Léo Bodnar et avec les même controles (XPNDR_1_DEC et XPNDR_1_INC) fonctionnent très bien.

J'ai essayé avec CHANGEBIT=0, &Enc_Xpndr_1 sans aucun résultat.

Merci de m'aider à approfondir sioc.

Dernière modification par Neutrino (27-04-2017 07:59:23)

mameloose · [↑]

Oula non il ne faut pas utiliser les bits pour la radio mais directement l'offset du transpondeur Jte fais un exemple cette après-midi quand je rentre

mameloose · [↑]

alors je texplique

l'offset de controle pour le transpondeur c'est la $0354 de longueur 2 donc tu la declare puis tu declare ton encodeur !

la valeur de loffset est en binaire donc on convertit ca avec la fonction TOBCD

donc dans le code quand tu tourne ton encodeur tu incremente une variable vide que j'ai crée qui elle meme enverra la bonne valeur a loffset pour controler ca dans fsx ou p3d

pour le code ca donne ca :

Var 0001, name TRANSPONDEUR, Link FSUIPC_INOUT, Offset $0354, Length 2

Var 0002, name ENCODEURXPDR, Link IOCARD_ENCODER, Input 2, Aceleration 1, Type 2
{
L0 = &ENCODEURXPDR
IF L0 > 0
{
&resultantexpdr = &resultantexpdr + 1
}
IF L0 < 0
{
&resultantexpdr = &resultantexpdr - 1
}
}

Var 0003, name resultantexpdr, Value 1200
{
&TRANSPONDEUR = TOBCD &resultantexpdr
}

Neutrino · [↑]

Merci Greg pour ta disponibilité et ta réactivité.

Ton code fonctionne quasiment bien, à un détail près:

Incrément:
init = 1200
1er inc = 1201
2ieme inc = 1202
.....
7 inc = 1207
8 inc = 1200
9 inc = 1201
10 inc = 1210
11 inc = 1211
... etc

Décrément:
init = 1200
1er déc = 1111
2ieme dec = 1110
3 dec = 1117
4 dec = 1116
...
10 dec = 1110
11 dec = 1101
12 dec = 1100
... etc

Désolé, j'aurai bien aimé pour toi que cela fonctionne au premier coup

mameloose · [↑]

oui c'etait pour lexemple jai fais ca vite fait je dois savoir un truc pour te faire un code complet :

combien dencodeur utilisera tu pour changer la frequence ?
parce qu'avec un seul si tu doit afficher 5963 tes pas couché a tourner la molette

Neutrino · [↑]

= 4 encodeurs

mameloose · [↑]

OK j'avais oublié dans le code que le transpondeur incremente de 0 à 7
Jte fais la modif cette après-midi

mameloose · [↑]

bon alors 4 encodeurs ca fait beaucoup je t'ai fais un code pour deux encodeur le premier bouge les deux premiers chiffre donc de zero a 77 et le deuxieme les deux derniers chiffres !

si tu veux un code a 4 encodeurs ya pas de soucis je te le modifie mais bon ca evite trop dencodeur pour un simple transpondeur ....

voila le code bon ca parait compliqué mais le transpondeur c'est particulier a programmer donc en gros je fais afficher la valeurs voulut dans des variables interne avec tes encodeurs qui ensuite se fusionne pour donner un resultat a 4 chiffre genre 1200 puis linformation est envoyé a loffset du transpondeur ....

voila

// *****************************************************************************
// * Config_SIOC ver 4.5 - By Manuel Velez - www.opencockpits.com
// *****************************************************************************
// * FileName : sioc.txt
// * Date : 28/04/2017

Var 0001, name TRANSPONDEUR, Link FSUIPC_INOUT, Offset $0354, Length 2

Var 0002, name ENCODEURXPDR1, Link IOCARD_ENCODER, Input 2, Aceleration 1, Type 2
{
L0 = &ENCODEURXPDR1
&chiffre2 = &chiffre2 + L0
}

Var 0003, name ENCODEURXPDR2, Link IOCARD_ENCODER, Input 4, Aceleration 1, Type 2
{
L0 = &ENCODEURXPDR2
&chiffre4 = &chiffre4 + L0
}

Var 0004, name chiffre1, Value 1
{
CALL &resultat
IF &chiffre1 > 7
{
&chiffre1 = 0
}
IF &chiffre1 < 0
{
&chiffre1 = 7
}
}

Var 0005, name chiffre2, Value 2
{
CALL &resultat
IF &chiffre2 > 7
{
&chiffre2 = 0
&chiffre1 = &chiffre1 + 1
}
IF &chiffre2 < 0
{
&chiffre2 = 7
&chiffre1 = &chiffre1 - 1
}
}

Var 0006, name chiffre3
{
CALL &resultat
IF &chiffre3 > 7
{
&chiffre3 = 0
}
IF &chiffre3 < 0
{
&chiffre3 = 7
}
}

Var 0007, name chiffre4
{
CALL &resultat
IF &chiffre4 > 7
{
&chiffre4 = 0
&chiffre3 = &chiffre3 + 1
}
IF &chiffre4 < 0
{
&chiffre4 = 7
&chiffre3 = &chiffre3 - 1
}
}

Var 0008, name resultat, Link SUBRUTINE
{
L0 = &chiffre1 * 1000
L1 = &chiffre2 * 100
L0 = L0 + L1
L1 = &chiffre3 * 10
L0 = L0 + L1
L0 = L0 + &chiffre4
&resultat = L0
&TRANSPONDEUR = TOBCD &resultat
}

Neutrino · [↑]

Et bien écoute, CHAPEAU !!!!

Bravo Greg cela fonctionne.
De toute façon je n'aurais pas pu inventer ce code tout seul ...

Sur le Cherokee de chez A2A, le transpondeur est un Bendix King KT76A avec 4 boutons donc je l'ai modélisé avec 4 encodeurs.

S'il te plaît je préfère la modification de ton code pour 4 encodeurs.

Pour l'instant mes piètres connaissances en sioc font que je suis incapable de décortiquer ton code pour le comprendre, c'est vrai que l'on continue par du lourd après la saga de l'encodeur Elma E37.

Question:
Pourquoi ne peut-on pas utiliser la technique du joystick64 et lui affecter avec fsuipc un control ? voir mon post 178.

mameloose · [↑]

alors tout simplement parce que la fonction joystick c'est un peu pour depanner
quand tu as les offset il faut toujours utiliser en priorité et surtout pour une fonction encodeur !
normalement les joystick sont de simple boutons ..

jte fais le code avec 4 encodeurs alors ....

mameloose · [↑]

voila donc encodeur 1 a 4 pour chaque chiffre et pour les entrées j'ai mis le 1 sur 2et 3 le 2 sur 4et5 ect ...

// *****************************************************************************
// * Config_SIOC ver 4.5 - By Manuel Velez - www.opencockpits.com
// *****************************************************************************
// * FileName : sioc.txt
// * Date : 28/04/2017

Var 0001, name TRANSPONDEUR, Link FSUIPC_INOUT, Offset $0354, Length 2

Var 0002, name ENCODEURXPDR1, Link IOCARD_ENCODER, Input 2, Aceleration 1, Type 2
{
L0 = &ENCODEURXPDR1
&chiffre1 = &chiffre1 + L0
}

Var 0003, name ENCODEURXPDR2, Link IOCARD_ENCODER, Input 4, Aceleration 1, Type 2
{
L0 = &ENCODEURXPDR2
&chiffre2 = &chiffre2 + L0
}

Var 0004, name chiffre1, Value 1
{
CALL &resultat
IF &chiffre1 > 7
{
&chiffre1 = 0
}
IF &chiffre1 < 0
{
&chiffre1 = 7
}
}

Var 0005, name chiffre2, Value 2
{
CALL &resultat
IF &chiffre2 > 7
{
&chiffre2 = 0
}
IF &chiffre2 < 0
{
&chiffre2 = 7
}
}

Var 0006, name chiffre3
{
CALL &resultat
IF &chiffre3 > 7
{
&chiffre3 = 0
}
IF &chiffre3 < 0
{
&chiffre3 = 7
}
}

Var 0007, name chiffre4
{
CALL &resultat
IF &chiffre4 > 7
{
&chiffre4 = 0
}
IF &chiffre4 < 0
{
&chiffre4 = 7
}
}

Var 0008, name resultat, Link SUBRUTINE
{
L0 = &chiffre1 * 1000
L1 = &chiffre2 * 100
L0 = L0 + L1
L1 = &chiffre3 * 10
L0 = L0 + L1
L0 = L0 + &chiffre4
&resultat = L0
&TRANSPONDEUR = TOBCD &resultat
}

Var 0009, name ENCODEURXPDR3, Link IOCARD_ENCODER, Input 6, Aceleration 1, Type 2
{
L0 = &ENCODEURXPDR3
&chiffre3 = &chiffre3 + L0
}

Var 0010, name ENCODEURXPDR4, Link IOCARD_ENCODER, Input 8, Aceleration 1, Type 2
{
L0 = &ENCODEURXPDR4
&chiffre4 = &chiffre4 + L0
}

Neutrino · [↑]

C'est parfait, il n'y a rien à dire - c'est du bon travail!

Cela mérite +1

Bon j'ai pas trop compris l'histoire de la subroutine, mais cela viendra....

Merci Greg

mameloose · [↑]

Lol une subroutine c'est une case dans laquelle tu peux créer une formule avec plusieurs informations qui vont appeler cette formule en gros

boutondair · [↑]

Merci Greg, je vais le garder de coté pour mon TB30

David

mameloose · [↑]

Ah bah content que ça serve à tout le monde lol

Neutrino · [↑]

Je rencontre une impossibilité à utiliser la 8 ieme position analogique d'une carte BU0836A.
J'explique:
Une carte BU0836A possède 8 analog inputs numérotés de 1 à 8. Avec Fsuipc, onglet Axis assignment, les connexions se trouvent affectées des lettres X,Y,Z,U,V,R,S pour les 7 premières et la 8 ième devrait prendre la lettre T. Hors chez moi une nouvelle fois la lettre S est proposée !
Est-ce que quelqu'un aurait une idée ?

Merci pour l'aide.

Michel

Neutrino · [↑]

Le bloc radios de mon Cherokee est terminé. Tous les contacts ont été simulés sauf la série Speaker de la boîte de mélange car j'utilise seulement Phone de Com1 à ADF.

Vue sur l'arrière du bloc radios fixé sur un support provisoire.

Les interrupteurs et encodeurs sont raccordés aux cartes de connexions déportées avec des connecteurs à sertir. Ces mêmes cartes de connexions déportées sont fixées au tableau de bord et reliées aux cartes Master ou BU0836A par nappe de câbles. Ce sont ces nappes de câbles que je brancherai/débrancherai pour changer de tableau de bord et piloter un autre avion.

Je trouve le résultat répondant à mes attentes initiales, à savoir simuler tous les contacts du tableau de bord mais sans compliquer avec de l'affichage et des leds.
Je suis partisan du 20/80: 20% d'effort pour 80% de résultat --- ensuite il faudrait beaucoup plus d'efforts pour peu de résultats supplémentaires.....
Je pourrai toujours plus tard fabriquer une radio avec de l'affichage, histoire d'essayer mais cela demande du temps et surtout de bien concevoir la réalisation parce que cela est petit, tout petit et qu'il n'y a pas beaucoup de place pour tout loger.

Côté programmation je disposais d'un document qui récapitule quasiment tous les controls mais avec quelques imprécisions A2A Cherokee 180 - Variable list.pdf
Ensuite il faut compléter le travail avec l'édition des variables L:vars: Bernard (Tabard57) en fait une explication sur son blog.
Il existe quelque fois un ensemble de fichiers : Piper Cherokee module Linda bien utiles à utiliser conjointement avec la fonction Tracer de Linda pour tester le fonctionnement de ces variables et des Fsx Controls.

Ces différents outils permettent donc de connaitre les Offsets, les L:vars et les Fsx Control à utiliser pour asservir les contacts qui sont raccordés à des cartes Master de chez Opencockpits et à des cartes BU0836A de chez Leo Bodnar. Le choix de l'une ou de l'autre carte se fait naturellement :
- Leo Bodnar pour les encodeurs doubles Elma E37 (non supportés par sioc) et les contacts gérés par Ezdok (Ezdok ne reconnait pas les cartes OC en tant que cartes joystick)
- OpenCockpits pour tout le reste, l'avantage étant de pouvoir écrire du code sioc quand cela le nécessite (néanmoins il est possible de programmer en langage Lua et d'utiliser Linda pour gérer des contacts branchés sur des cartes Leo Bodnar).

L'utilisation d'une L:var avec sioc se fait par le biais de l'offset $3340, $3344, $3348, $334C etc... affecté du bit 0 à 31. Aussi appelé le Joystick64, cet offset permet d'affecter jusqu'à 288 commandes (9 offsets x 32 bits = 288).
En langage sioc cela donne:

Var 0010, name AudioSelOff, Link FSUIPC_INOUT, Offset $3340, Length 4 // ici c'est l'offset $3340 qui est choisit

Var 0400, name AudioSelOffSw, Link IOCARD_SW, Input 36
{
IF &AudioSelOffSw = 1
{
&AudioSelOff = SETBIT 0 // utilisation du bit 0
}
ELSE
{
&AudioSelOff = CLEARBIT 0 // utilisation du bit 0
}
}
Ensuite l'affectation de la L:var à cet offset ce fait avec Fsuipc:

L'utilisation d'un control FSX se fait par le biais de l'offset $3110. Aussi appelé "le couteau suisse", cet offset peut-être affecté d'un control fsx. En langage sioc cela donne:

Var 0051, name Gns400Nrst, Link FSUIPC_OUT, Offset $3110, Length 4 // on utilise l'offset $3110

Var 0438, name Gns400NrstSw, Link IOCARD_SW, Input 48
{
IF &Gns400NrstSw = 1
{
&Gns400Nrst = 66604 // affectation du control 66604
&Gns400Nrst = DELAY 0 ,10
}
}

Le restant du tableau de bord devrait se réaliser plus facilement parce que les contacts et potentiomètres sont plus espacés les uns des autres.

En ce moment je bidouille l'accouplement d'un cylindre de verrou de mon ancienne porte de garage avec un interrupteur rotatif Lorlin CK1029 pour réaliser le démarreur. A défaut d'utiliser des pièces d'origine de chez Piper, je recycle des pièces qui ont quand même du vécu .....

A suivre...

Michel

Dernière modification par Neutrino (16-06-2018 07:16:27)

greg · [↑]

Merci pour les inf°

TABAR57 · [↑]

Bonjour,

Je te félicite Michel pour ton câblage et ta réalisation , c'est super propre , il faut que j'en prenne de la graine ...
Et merci aussi de m'avoir cité dans ton message , çà me fait plaisir.

Courage pour la suite, çà prend forme BRAVO

Cordialement

Bernard

Dernière modification par TABAR57 (13-07-2017 18:32:57)

Neutrino · [↑]

Merci les amis pour vos encouragements, vous aussi vous me faites plaisir en donnant votre point de vue.

Et puis comme vous l'avez compris, ces explications sont écrites pour tous les anonymes des forums qui cherchent des réponses aux questions qu'ils se posent... parce que vous le savez encore bien plus que moi, lorsque l'on est débutant et que l'on s'attelle à une réalisation, il y a une foultitude d'interrogations qui ne trouvent pas facilement leurs réponses.

Cette discussion à été ouverte en formulant un objectif - celui de la réalisation d'un tableau de bord "semi opératif " - et en s'interrogeant sur une méthode de réalisation - qui ne soit pas trop longue ni trop onéreuse - afin d'envisager la possibilité de fabriquer d'autres tableau de bord "light" et "plug and play".

Ah! quel plaisir de vérifier à l'écran que la gauge s'anime en manipulant un encodeur ou un poussoir sur son tableau de bord .....

On ne peut que encourager tous ceux qui voudraient essayer à faire les premiers pas en ce sens.

Michel

TABAR57 · [↑]

C'est plaisant d'apporter une petite pierre à l'édifice

Je ne doute pas qu'avec ta méthode ton tableau de bord sera pleinement opérationnel et non pas semi, c'est tout à fait possible, par contre du plug and play j'y crois pas trop

Pour ma part, çà fait 15 jours que je bosse sur l'interfaçage d'un vrai glareshield de B200 et c'est vraiment pas simple, tous les jours je me gratte la tête sur les nouvelles fonctionnalités à mettre en place par exemple les voyants de test feux moteurs

Courage , c'est long ...

Bernard

Dernière modification par TABAR57 (13-07-2017 21:30:36)

Neutrino · [↑]

Exact.

Pour me faciliter le cablage j'ai créé des cartes de connexions déportées, en réaffectant son ground respectif à chaque input.

J'explique:
Prenons par exemple un connecteur male 20 connexions soit 2 rangées de 10 pins ( celui provenant de la carte OC ):
- la première rangées aura les inputs 0 à 8 et
- la seconde rangées aura le ground correspondant en commun
Ainsi chaque connecteur femelle ( celui provenant du contact tdb) aura son input avec son ground en face de lui.

Pour m'y retrouver je crée un tableau qui me permet d'affecter mes connecteurs. Par exemple pour Master#0 J3, les inputs 18 à 22 sont occupés par un connecteur 10 connections ( 2x5 ), sur le tableau les cellules Xpdr Off à Xpdr Tst sont encadrées pour signaler que c'est un connecteur 5 inputs. Idem avec 24 à 25 avec un connecteur 2 inputs. Il m'est facile de boucher mes "trous" avec des connecteurs 1 input.

Je ne sais pas si je me fait bien comprendre - c'est plus facile à réaliser plutôt qu'à expliquer -=8
Il est certain que 9 inputs pour un ground est une vraie contrainte!

Dernière modification par Neutrino (16-06-2018 07:17:18)

Neutrino · [↑]

par contre du plug and play j'y crois pas trop

Bernard, si l'avenir montre que tu avais raison, j'aurai perdu mon pari....

Pour l'instant je m'organise pour que physiquement mon tdb ne soit relié aux cartes OC et LB que par des connecteurs avec nappes 40 fils.
Ensuite il "suffit" d'archiver les fichiers correspondants, à savoir: le script sioc, le fsuipc.ini et la config Ezdok.

Enfin bon, c'est mon idée du moment....

#176 [↑][↓] 08-04-2017 12:03:16

Re : [P3D][FSX] Tentative de méthode de réalisation

#177 [↑][↓] 08-04-2017 13:20:24

Re : [P3D][FSX] Tentative de méthode de réalisation

#178 [↑][↓] 27-04-2017 07:52:15

Re : [P3D][FSX] Tentative de méthode de réalisation

#179 [↑][↓] 27-04-2017 08:21:28

Re : [P3D][FSX] Tentative de méthode de réalisation

#180 [↑][↓] 27-04-2017 15:19:44

Re : [P3D][FSX] Tentative de méthode de réalisation

#181 [↑][↓] 27-04-2017 19:35:31

Re : [P3D][FSX] Tentative de méthode de réalisation

#182 [↑][↓] 27-04-2017 20:24:39

Re : [P3D][FSX] Tentative de méthode de réalisation

#183 [↑][↓] 28-04-2017 05:19:31

Re : [P3D][FSX] Tentative de méthode de réalisation

#184 [↑][↓] 28-04-2017 05:33:47

Re : [P3D][FSX] Tentative de méthode de réalisation

#185 [↑][↓] 28-04-2017 14:32:45

Re : [P3D][FSX] Tentative de méthode de réalisation

#186 [↑][↓] 28-04-2017 15:31:41

Re : [P3D][FSX] Tentative de méthode de réalisation

#187 [↑][↓] 28-04-2017 15:50:08

Re : [P3D][FSX] Tentative de méthode de réalisation

#188 [↑][↓] 28-04-2017 15:55:16

Re : [P3D][FSX] Tentative de méthode de réalisation

#189 [↑][↓] 28-04-2017 18:18:04

Re : [P3D][FSX] Tentative de méthode de réalisation

#190 [↑][↓] 28-04-2017 18:42:43

Re : [P3D][FSX] Tentative de méthode de réalisation

#191 [↑][↓] 02-05-2017 14:35:27

Re : [P3D][FSX] Tentative de méthode de réalisation

#192 [↑][↓] 02-05-2017 17:05:54

Re : [P3D][FSX] Tentative de méthode de réalisation

#193 [↑][↓] 12-06-2017 08:08:15

Re : [P3D][FSX] Tentative de méthode de réalisation

#194 [↑][↓] 10-07-2017 15:06:23

Re : [P3D][FSX] Tentative de méthode de réalisation

#195 [↑][↓] 12-07-2017 16:55:57

Re : [P3D][FSX] Tentative de méthode de réalisation

#196 [↑][↓] 13-07-2017 18:32:12

Re : [P3D][FSX] Tentative de méthode de réalisation

#197 [↑][↓] 13-07-2017 20:29:00

Re : [P3D][FSX] Tentative de méthode de réalisation

#198 [↑][↓] 13-07-2017 21:21:59

Re : [P3D][FSX] Tentative de méthode de réalisation

#199 [↑][↓] 13-07-2017 22:00:26

Re : [P3D][FSX] Tentative de méthode de réalisation

#200 [↑][↓] 13-07-2017 22:14:20

Re : [P3D][FSX] Tentative de méthode de réalisation

Pied de page des forums